Index: src/system/ldscripts/x86_64/boot_loader_bios_x86_64.ld
===================================================================
--- src/system/ldscripts/x86_64/boot_loader_bios_x86_64.ld	(revision 0)
+++ src/system/ldscripts/x86_64/boot_loader_bios_x86_64.ld	(revision 0)
@@ -0,0 +1,33 @@
+OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
+OUTPUT_ARCH(i386)
+
+ENTRY(_start)
+SECTIONS
+{
+	. = 0x10000;
+
+	/* text/read-only data */
+	.text :	{ *(.text .gnu.linkonce.t.*) }
+
+	. = ALIGN(0x4);
+	__ctor_list = .;
+	.ctors : { *(.ctors) }
+	__ctor_end = .;
+
+	.rodata : { *(.rodata .rodata.*) }
+
+	/* writable data  */
+	. = ALIGN(0x1000);
+	__data_start = .;
+	.data : { *(.data .gnu.linkonce.d.*) }
+
+	/* uninitialized data (in same segment as writable data) */
+	__bss_start = .;
+	.bss : { *(.bss) }
+
+	. = ALIGN(0x1000);
+	_end = . ;
+
+	/* Strip unnecessary stuff */
+	/DISCARD/ : { *(.comment .note .eh_frame .dtors .stab .stabstr .debug*) }
+}
Index: src/system/ldscripts/x86_64/stage2.ld
===================================================================
--- src/system/ldscripts/x86_64/stage2.ld	(revision 0)
+++ src/system/ldscripts/x86_64/stage2.ld	(revision 0)
@@ -0,0 +1,28 @@
+OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
+OUTPUT_ARCH(i386)
+
+ENTRY(_start)
+SECTIONS
+{
+	. = 0x101000 + SIZEOF_HEADERS;
+
+	/* text/read-only data */
+	.text :	{ *(.text .gnu.linkonce.t.*) }
+
+	__ctor_list = .;
+	.ctors : { *(.ctors) }
+	__ctor_end = .;
+
+	.rodata : { *(.rodata .rodata.*) }
+
+	/* writable data  */
+	. = ALIGN(0x1000);
+	__data_start = .;
+	.data : { *(.data .gnu.linkonce.d.* .bss) }
+
+	. = ALIGN(0x1000);
+	_end = . ;
+
+	/* Strip unnecessary stuff */
+	/DISCARD/ : { *(.comment .note .eh_frame .dtors .stab .stabstr .debug*) }
+}
Index: src/system/ldscripts/x86_64/runtime_loader.ld
===================================================================
--- src/system/ldscripts/x86_64/runtime_loader.ld	(revision 0)
+++ src/system/ldscripts/x86_64/runtime_loader.ld	(revision 0)
@@ -0,0 +1,63 @@
+OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
+OUTPUT_ARCH(i386:x86-64)
+
+ENTRY(runtime_loader)
+SEARCH_DIR("libgcc");
+SECTIONS
+{
+	. = 0x00100000 + SIZEOF_HEADERS;
+
+	.interp : { *(.interp) }
+	.hash : { *(.hash) }
+	.dynsym : { *(.dynsym) }
+	.dynstr : { *(.dynstr) }
+	.rel.text : { *(.rel.text) *(.rel.gnu.linkonce.t*) }
+	.rela.text : { *(.rela.text) *(.rela.gnu.linkonce.t*) }
+	.rel.data : { *(.rel.data) *(.rel.gnu.linkonce.d*) }
+	.rela.data : { *(.rela.data) *(.rela.gnu.linkonce.d*) }
+	.rel.rodata : { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
+	.rela.rodata : { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
+	.rel.got : { *(.rel.got) }
+	.rela.got : { *(.rela.got) }
+	.rel.ctors : { *(.rel.ctors) }
+	.rela.ctors : { *(.rela.ctors) }
+	.rel.dtors : { *(.rel.dtors) }
+	.rela.dtors : { *(.rela.dtors) }
+	.rel.init : { *(.rel.init) }
+	.rela.init : { *(.rela.init) }
+	.rel.fini : { *(.rel.fini) }
+	.rela.fini : { *(.rela.fini) }
+	.rel.bss : { *(.rel.bss) }
+	.rela.bss : { *(.rela.bss) }
+	.rel.plt : { *(.rel.plt) }
+	.rela.plt : { *(.rela.plt) }
+	.init : { *(.init) } =0x9090
+	.plt : { *(.plt) }
+
+	/* text/read-only data */
+	.text :	{ *(.text .gnu.linkonce.t.*) }
+
+	.rodata : { *(.rodata) }
+
+	/* writable data  */
+  	. = ALIGN(0x1000) + (. & (0x1000 - 1));
+	__data_start = .;
+	PROVIDE(_data_start = .);
+	.data : { *(.data .gnu.linkonce.d.*) }
+
+	__ctor_list = .;
+	PROVIDE (_ctor_list = .);
+	.ctors : { *(.ctors) }
+	PROVIDE (__ctor_end = .);
+
+
+	/* uninitialized data (in same segment as writable data) */
+	PROVIDE (__bss_start = .);
+	.bss : { *(.bss) }
+
+	. = ALIGN(0x1000);
+	PROVIDE (_end = .);
+
+	/* Strip unnecessary stuff */
+	/DISCARD/ : { *(.comment .note .eh_frame .dtors) }
+}
Index: src/system/ldscripts/x86_64/kernel.ld
===================================================================
--- src/system/ldscripts/x86_64/kernel.ld	(revision 0)
+++ src/system/ldscripts/x86_64/kernel.ld	(revision 0)
@@ -0,0 +1,66 @@
+OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
+OUTPUT_ARCH(i386:x86-64)
+
+ENTRY(_start)
+SEARCH_DIR("libgcc");
+SECTIONS
+{
+	. = 0x80000000 + SIZEOF_HEADERS; 
+
+	.interp : { *(.interp) }
+	.hash : { *(.hash) }
+	.dynsym : { *(.dynsym) }
+	.dynstr : { *(.dynstr) }
+	.rel.text : { *(.rel.text) *(.rel.gnu.linkonce.t*) }
+	.rela.text : { *(.rela.text) *(.rela.gnu.linkonce.t*) }
+	.rel.data : { *(.rel.data) *(.rel.gnu.linkonce.d*) }
+	.rela.data : { *(.rela.data) *(.rela.gnu.linkonce.d*) }
+	.rel.rodata : { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
+	.rela.rodata : { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
+	.rel.got : { *(.rel.got) }
+	.rela.got : { *(.rela.got) }
+	.rel.ctors : { *(.rel.ctors) }
+	.rela.ctors : { *(.rela.ctors) }
+	.rel.dtors : { *(.rel.dtors) }
+	.rela.dtors : { *(.rela.dtors) }
+	.rel.init : { *(.rel.init) }
+	.rela.init : { *(.rela.init) }
+	.rel.fini : { *(.rel.fini) }
+	.rela.fini : { *(.rela.fini) }
+	.rel.bss : { *(.rel.bss) }
+	.rela.bss : { *(.rela.bss) }
+	.rel.plt : { *(.rel.plt) }
+	.rela.plt : { *(.rela.plt) }
+	.init : { *(.init) } =0x9090
+	.plt : { *(.plt) }
+
+	/* text/read-only data */
+	.text :	{ *(.text .gnu.linkonce.t.*) } =0x9090
+
+	.rodata : { *(.rodata) }
+
+	/* writable data  */
+	. = ALIGN(0x1000);
+	__data_start = .;
+	.data : { *(.data .gnu.linkonce.d.*) }
+
+	. = ALIGN(0x4);
+	__ctor_list = .;
+	.ctors : { *(.ctors) }
+	__ctor_end = .;
+	__dtor_list = .;
+	.dtors : { *(.dtors) }
+	__dtor_end = .;
+	.got : { *(.got.plt) *(.got) }
+	.dynamic : { *(.dynamic) }
+	
+	/* uninitialized data (in same segment as writable data) */
+	__bss_start = .;
+	.bss : { *(.bss) }
+
+	. = ALIGN(0x1000);
+	_end = . ;
+
+	/* Strip unnecessary stuff */
+	/DISCARD/ : { *(.comment .note .eh_frame) }
+}